let unpackOptionals =
      https://raw.githubusercontent.com/dhall-lang/dhall-lang/v21.1.0/Prelude/List/unpackOptionals.dhall sha256:0cbaa920f429cf7fc3907f8a9143203fe948883913560e6e1043223e6b3d05e4

let concat =
      https://raw.githubusercontent.com/dhall-lang/dhall-lang/v21.1.0/Prelude/List/concat.dhall sha256:54e43278be13276e03bd1afa89e562e94a0a006377ebea7db14c7562b0de292b

let showNat =
      https://raw.githubusercontent.com/dhall-lang/dhall-lang/v21.1.0/Prelude/Natural/show.dhall sha256:684ed560ad86f438efdea229eca122c29e8e14f397ed32ec97148d578ca5aa21

let xmobar = ../xmobar.dhall

let MultiCoreTemp =
      { Type =
              xmobar.DefaultArguments.Type
          //\\  { refreshRate : Natural
                , maxIconPattern : Optional Text
                , avgIconPattern : Optional Text
                , minTemp : Natural
                , maxTemp : Natural
                , hwMonitorPath : Optional Text
                }
      , default =
              xmobar.DefaultArguments.default
          //  { maxIconPattern = None Text
              , avgIconPattern = None Text
              , minTemp = 0
              , maxTemp = 100
              , hwMonitorPath = None Text
              }
      }

let toFlags =
      \(args : MultiCoreTemp.Type) ->
        concat
          Text
          ( unpackOptionals
              (List Text)
              [ xmobar.addTextFlag "--max-icon-pattern" args.maxIconPattern
              , xmobar.addTextFlag "--avg-icon-pattern" args.avgIconPattern
              , Some [ "--mintemp", showNat args.minTemp ]
              , Some [ "--maxtemp", showNat args.maxTemp ]
              , xmobar.addTextFlag "--hwmon-path" args.hwMonitorPath
              ]
          )

let toPositionalArgs =
      \(args : MultiCoreTemp.Type) -> [ showNat args.refreshRate ] : List Text

in  { MultiCoreTemp
    , runMultiCoreTemp =
        xmobar.mkRunner
          MultiCoreTemp.Type
          (\(x : MultiCoreTemp.Type) -> x.(xmobar.DefaultArguments.Type))
          toFlags
          toPositionalArgs
          "MultiCoreTemp"
          (Some 0)
    }